الثلاثاء، 28 أكتوبر 2025

Support and Resistance Levels with Breaks [LuxAlgo]

مستويات الدعم والمقاومة مع كسرها — LuxAlgo (Pine Script)

مستويات الدعم والمقاومة مع كسرها LuxAlgo

شرح مؤشر Pine Script يحدد خطوط الدعم/المقاومة من المحاور ويُظهر إشارات الكسر المشروطة بالحجم مع تمييز ظلال الشموع.
```

هذا المؤشر يرسم خطوط مقاومة أعلى السعر وخطوط دعم أسفله اعتمادًا على القمم والقيعان المحورية (Pivots)، ثم يضع وسومًا عند حدوث كسر حقيقي لتلك المستويات بشرط توفر زخم حجمي ملحوظ. كما يميّز بين كسور ناتجة عن ظلال شموع صعودية/هبوطية وبين كسور مصحوبة بإغلاق واضح.

فكرة العمل

تحديد المستويات

يتم استخراج آخر قمة/قاع محورية باستخدام pivothigh وpivotlow مع نافذتين leftBars وrightBars (افتراضيًا 15 لكلٍ منهما). تُرسم القمم كمقاومة باللون الأحمر، والقيعان كدعم باللون الأزرق. يتم تعويض الرسم بمقدار rightBars+1 لضبط توقيت ظهور المستوى بعد اكتمال المحور.

تأكيد الكسر بالحجم

يُحسب مُذبذب حجم بسيط: متوسط أُسّي لحجم 5 شموع (EMA(5)) مقابل 10 (EMA(10))، ثم النسبة المئوية osc = 100 * (EMA5 - EMA10) / EMA10. لا تُقبل إشارة الكسر إلا إذا تجاوز osc العتبة volumeThresh (افتراضيًا 20).

قواعد الكسر

  • كسر مقاومة: crossover(close, highUsePivot) مع حجم مُعزَّز.
  • كسر دعم: crossunder(close, lowUsePivot) مع حجم مُعزَّز.
  • يُستبعد الكسر إذا كانت الشمعة ذات ظل مقابل قوي يوحي بعدم الإغلاق فوق/تحت المستوى.

ظلال الشموع (Wicks)

إذا كان الاختراق لأعلى مصحوبًا بظل سفلي أطول من جسم الشمعة (open - low > close - open) تُوسَم كـ Bull Wick. والعكس لأسفل (open - close < high - open) تُوسَم Bear Wick. هذه الوسوم تُظهر أن الحركة قد تكون مدفوعة بظل لا بإغلاق قوي.

المدخلات

  • Show Breaks — إظهار/إخفاء وسوم الكسر والظلال.
  • Left Bars / Right Bars — عرض نافذة المحور لتحديد القمم/القيعان (كلما زادت كان المستوى أقوى ولكن أقل تكرارًا).
  • Volume Threshold — عتبة المُذبذب الحجمي osc بالمئة لتأكيد الكسر (افتراضي 20%).

المؤشرات المُستخدمة

  • Pivots: pivothigh وpivotlow لاستخراج مستويات المقاومة/الدعم.
  • Volume EMA: متوسطان أُسّيان لحجم التداول 5 و10.
  • Volume Oscillator: النسبة المئوية بين EMA5 وEMA10 لتصفية الكسور الضعيفة.
  • إشعارات: alertcondition عند كسر الدعم/المقاومة بشرط الحجم.

الإشارات

  • B (أخضر): كسر مقاومة مع حجم داعم.
  • B (أحمر): كسر دعم مع حجم داعم.
  • Bull Wick / Bear Wick: اختراق/كسر يُحتمل أنه مدفوع بظلال شموع أكثر من كونه إغلاقًا قويًا.

تظهر خطوط Resistance باللون الأحمر وخطوط Support بالأزرق، بينما تظهر الوسوم فوق/أسفل الشموع بحسب نوع الكسر.

طريقة الاستخدام

  1. افتح منصة TradingView وأضِف المؤشر عبر نافذة Pine Editor بلصق الكود أدناه وحفظه ثم إضافته إلى الرسم.
  2. اختر الإطار الزمني المناسب لاستراتيجيتك (يعمل على أي إطار؛ المستويات الأوسع تظهر على الأطر الأعلى).
  3. اضبط Left/Right Bars حسب رغبتك لقوة/كثافة المستويات.
  4. اضبط Volume Threshold ليتوافق مع الأصل/السيولة؛ رفعه يقلل الإشارات الضعيفة.
  5. فعّل Show Breaks لإظهار وسوم الكسر والظلال، ويمكن الاعتماد على alertcondition لتنبيه تلقائي.

كود Pine Script

// This work is licensed under a Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) https://creativecommons.org/licenses/by-nc-sa/4.0/
```

// © LuxAlgo

//@version = 4
study(title=" Support and Resistance Levels with Breaks",shorttitle = " Support and Resistance Levels with Breaks [LuxAlgo]", overlay = true ,  max_bars_back=1000)
//
toggleBreaks  = input(true, title = "Show Breaks" )
leftBars  = input(15, title = "Left Bars ")
rightBars  = input(15, title = "Right Bars")
volumeThresh  = input(20, title = "Volume Threshold")
//
highUsePivot = fixnan(pivothigh(leftBars, rightBars)[1])
lowUsePivot = fixnan(pivotlow(leftBars, rightBars)[1])
r1 = plot(highUsePivot, color=change(highUsePivot) ? na : #FF0000,  linewidth=3, offset=-(rightBars+1), title="Resistance")
s1 = plot(lowUsePivot, color=change(lowUsePivot) ? na : #233dee,  linewidth=3, offset=-(rightBars+1), title="Support")

//Volume %
short = ema(volume, 5)
long = ema(volume, 10)
osc = 100 * (short - long) / long

//For breaks with volume
plotshape(toggleBreaks and crossunder(close,lowUsePivot) and not (open - close < high - open) and osc > volumeThresh, title = "Break", text = 'B', style = shape.labeldown, location = location.abovebar, color= color.red,textcolor = color.white, transp = 0, size = size.tiny)
plotshape(toggleBreaks and crossover(close,highUsePivot ) and not(open - low > close - open) and osc > volumeThresh, title = "Break", text = 'B', style = shape.labelup, location = location.belowbar, color= color.green,textcolor = color.white, transp = 0, size = size.tiny)

//For bull / bear wicks
plotshape(toggleBreaks and crossover(close,highUsePivot ) and open - low > close - open , title = "Break", text = 'Bull Wick', style = shape.labelup, location = location.belowbar, color= color.green,textcolor = color.white, transp = 0, size = size.tiny)
plotshape(toggleBreaks and crossunder(close,lowUsePivot) and open - close < high - open , title = "Break", text = 'Bear Wick', style = shape.labeldown, location = location.abovebar, color= color.red,textcolor = color.white, transp = 0, size = size.tiny)

alertcondition(crossunder(close,lowUsePivot) and osc > volumeThresh , title = "Support Broken" , message = "Support Broken")
alertcondition(crossover(close,highUsePivot) and osc > volumeThresh, title = "Resistance Broken" , message = "Resistance Broken")
```

تنبيه مهم

المحتوى تعليمي بحت ولا يُعد نصيحة استثمارية. التداول ينطوي على مخاطر عالية؛ قم بالاختبار الخلفي واتباع إدارة رأس مال مناسبة.

افتح في TradingView
الترخيص: CC BY-NC-SA 4.0 — © LuxAlgo
  • Pine Script
  • TradingView
  • LuxAlgo
  • دعم ومقاومة
  • حجم التداول
```
مرسلة بواسطة في
التسميات:

ليست هناك تعليقات:

إرسال تعليق

الاشتراك في: تعليقات الرسالة (Atom)